import org.jetbrains.kotlin.gradle.tasks.KotlinCompile

val buildVersion: String by project
val patchVersion: String by project
val gafVersion: String by project
val extVersion: String? by project

group = "jit.xms"
version = buildVersion

extra["gafVersion"] = gafVersion
extra["xmsVersion"] = buildVersion
extra["extVersion"] = extVersion ?: buildVersion
extra["springCloudVersion"] = "Hoxton.SR5"
extra["fastjsonVersion"] = "1.2.72"
extra["jjwtVersion"] = "0.10.5"

val repoConf: String = System.getProperty("repoPath") ?: "/var/repo"
val repoPath: String = file("$rootDir").toPath().root.resolve(repoConf).toString()

plugins {
    java
    id("maven-publish")
    id("io.spring.dependency-management") version "1.0.10.RELEASE"
    id("org.springframework.boot") version "2.3.3.RELEASE" apply false
    kotlin("jvm") version "1.3.72"
    kotlin("plugin.spring") version "1.3.72" apply false
    kotlin("plugin.jpa") version "1.3.72" apply false
}

repositories {
    // 阿里云镜像
    maven { url = uri("https://maven.aliyun.com/repository/public") }
    maven { url = uri("https://maven.aliyun.com/repository/gradle-plugin") }
    maven { url = uri("https://maven.aliyun.com/repository/spring") }
    maven { url = uri("https://maven.aliyun.com/repository/spring-plugin") }
    // mavenCentral()
}

configure(subprojects.filter { it.name != "platform" }) {
    apply(plugin = "java")
    apply(plugin = "maven-publish")
    apply(plugin = "org.jetbrains.kotlin.jvm")

    java {
        disableAutoTargetJvm()
    }

    tasks.withType<JavaCompile> {
        options.encoding = "UTF-8"
        sourceCompatibility = "1.8"
        targetCompatibility = "1.8"
    }

    tasks.withType<KotlinCompile> {
        kotlinOptions {
            freeCompilerArgs = listOf("-Xjsr305=strict")
            jvmTarget = "1.8"
        }
    }

    repositories {
        maven {
            name = "localRepo"
            url = uri("file://$repoPath")
        }
        maven {
            name = "cc-lotus"
            url = uri("https://maven.cc-lotus.info/repository/maven-public/")
        }
        // 阿里云镜像
        maven { url = uri("https://maven.aliyun.com/repository/public") }
        maven { url = uri("https://maven.aliyun.com/repository/gradle-plugin") }
        maven { url = uri("https://maven.aliyun.com/repository/spring") }
        maven { url = uri("https://maven.aliyun.com/repository/spring-plugin") }
        // mavenCentral()
        jcenter()
    }

    publishing {
        repositories {
            maven {
                name = "localRepo"
                url = uri("file://$repoPath")
            }
        }
    }
}

task<Copy>("dist") {
    into("$buildDir/dist")
    project(":services:service-all") {
        from(tasks.withType<Jar>())
    }
    project(":apps:xms-all-in-one") {
        from(tasks.withType<Jar>())
    }
    project(":apps:app-agent") {
        from(tasks.withType<Jar>())
    }
}

tasks.register<Delete>("cleanDist") {
    delete("$rootDir/dist")
    delete("$buildDir/dist")
}
tasks.named("clean") {
    dependsOn(tasks.named("cleanDist"))
}
tasks.register("printProps") {
    val splitJars: String by project
    println(splitJars)
}