hkyy-service/xms-auth/services/build.gradle.kts

group = "jit.xms"
version = "1.0.0"

plugins {
    id("java")
    id("io.spring.dependency-management")
    id("org.springframework.boot") apply false
    kotlin("jvm")
    kotlin("plugin.spring")
    kotlin("plugin.jpa")
}

subprojects {
    apply(plugin = "java")
    apply(plugin = "org.springframework.boot")
    apply(plugin = "io.spring.dependency-management")
    apply(plugin = "org.jetbrains.kotlin.jvm")
    apply(plugin = "org.jetbrains.kotlin.plugin.spring")
    apply(plugin = "org.jetbrains.kotlin.plugin.jpa")

    dependencies {
        implementation(kotlin("reflect"))
        implementation(kotlin("stdlib-jdk8"))
//        implementation(fileTree("$rootDir/libs") { include("gaf-core-*.jar") })
//        implementation(fileTree("$rootDir/libs") { include("xms-core-*.jar") })
        implementation("cc-lotus.gaf3:gaf-core-shared:${property("gafVersion")}")
        implementation("cc-lotus.gaf3:gaf-core-services:${property("gafVersion")}")
        implementation("cc-lotus.gaf3:gaf-core-gateway:${property("gafVersion")}")
        implementation("jit.xms:xms-core-shared:${property("xmsVersion")}")
        implementation("jit.xms:xms-core-services:${property("xmsVersion")}")
        implementation(project(path = ":shared:util"))
        implementation("org.springframework.boot:spring-boot-starter-data-jpa")
        implementation("org.springframework.boot:spring-boot-starter-webflux")
        implementation("com.fasterxml.jackson.module:jackson-module-kotlin")
        implementation("org.springframework.cloud:spring-cloud-starter-openfeign")
        implementation("org.springframework.cloud:spring-cloud-starter-gateway")
        implementation("io.jsonwebtoken:jjwt-api:${property("jjwtVersion")}")
        implementation("io.jsonwebtoken:jjwt-impl:${property("jjwtVersion")}")
        implementation("io.jsonwebtoken:jjwt-jackson:${property("jjwtVersion")}")
        annotationProcessor("org.springframework.boot:spring-boot-configuration-processor")
        runtimeOnly("mysql:mysql-connector-java")
        implementation("javax.validation:validation-api")
        runtimeOnly("org.hibernate.validator:hibernate-validator")
    }
    dependencyManagement {
        imports {
            mavenBom("org.springframework.cloud:spring-cloud-dependencies:${property("springCloudVersion")}")
        }
    }

    tasks.register<Jar>(name = "libJar") {
        archiveBaseName.set("jit-xms-${project.name}-lib")
        from(project.the<SourceSetContainer>()["main"].output)
        include("jit/**")
        exclude {
            it.name.endsWith("Application.class")
        }
        exclude {
            it.name.endsWith("ApplicationKt.class")
        }
        exclude {
            it.name.endsWith("Application${'$'}Companion.class")
        }
    }
    tasks.build { dependsOn(tasks.named("libJar")) }

    tasks {
        processResources {
            filesMatching("application-db.yml") {
                // expand("db.user" to dbUser)
                expand(project.properties)
            }
        }
    }

    task<Copy>("dist") {
        into("$rootDir/dist/${project.name}")
        from(tasks.withType<org.springframework.boot.gradle.tasks.bundling.BootJar>())
        from("$projectDir/sh")
        from("$buildDir/resources/main") {
            include("*.yml")
            into("config")
        }
        from("$rootDir/sh") {
            into("sbin")
        }
    }

    configurations {
        create("lib")
    }

    artifacts {
        add("lib", tasks["libJar"])
    }
}

project(":services:cert-down") {
    dependencies {
        implementation(project(":services:multi-factor", configuration = "lib"))
        implementation(project(path = ":shared:multi-factor-api"))
        // implementation("jit.xms:xms-core-shared:${property("xmsVersion")}")
        // implementation("jit.xms:xms-core-services-lib:${property("xmsVersion")}")
    }
}

project(":services:multi-factor") {
    tasks.named<Copy>("dist") {
        from("$rootDir/libs") {
            into("lib")
        }
    }
    dependencies {
        implementation(project(path = ":shared:multi-factor-api"))
        // implementation("jit.xms:xms-core-shared:${property("xmsVersion")}")
        // implementation("jit.xms:xms-core-services-lib:${property("xmsVersion")}")
        runtimeOnly("net.java.dev.jna:jna:5.5.0")
        runtimeOnly(fileTree("$rootDir/libs") { include("*.jar") })
    }
}

tasks.forEach {
    it.enabled = false
}