import org.jetbrains.kotlin.gradle.tasks.KotlinCompile

plugins {
    java
    id("maven-publish")
    id("io.spring.dependency-management") version "1.0.11.RELEASE"
    id("org.springframework.boot") version "2.4.13" apply false
    kotlin("jvm") version "1.5.10"
    kotlin("plugin.spring") version "1.5.10" apply false
    kotlin("plugin.jpa") version "1.5.10" apply false
}

val buildVersion: String by project
val gafVersion: String by project

group = "llh.svs"
version = buildVersion
extra["gafVersion"] = gafVersion
extra["springCloudVersion"] = "2020.0.4"
extra["fastjsonVersion"] = "1.2.72"
extra["jjwtVersion"] = "0.10.5"

val repoConf: String = System.getProperty("repoPath") ?: "/var/repo"
val repoPath: String = file("$rootDir").toPath().root.resolve(repoConf).toString()

repositories {
    // 阿里云镜像
    maven { url = uri("https://maven.aliyun.com/repository/public") }
    maven { url = uri("https://maven.aliyun.com/repository/gradle-plugin") }
    maven { url = uri("https://maven.aliyun.com/repository/spring") }
    maven { url = uri("https://maven.aliyun.com/repository/spring-plugin") }
}

configure(subprojects.filter { it.name != "platform" }) {
    apply(plugin = "java")
    apply(plugin = "maven-publish")
    apply(plugin = "org.jetbrains.kotlin.jvm")

    java {
        disableAutoTargetJvm()
    }

    tasks.withType<JavaCompile> {
        options.encoding = "UTF-8"
        sourceCompatibility = "1.8"
        targetCompatibility = "1.8"
    }

    tasks.withType<KotlinCompile> {
        kotlinOptions {
            freeCompilerArgs = listOf("-Xjsr305=strict")
            jvmTarget = "1.8"
        }
    }

    repositories {
        maven {
            name = "localRepo"
            url = uri("file://$repoPath")
        }
        maven {
            name = "cc-lotus"
            url = uri("https://maven.cc-lotus.info/repository/maven-public/")
        }
        // 阿里云镜像
        maven { url = uri("https://maven.aliyun.com/repository/public") }
        maven { url = uri("https://maven.aliyun.com/repository/gradle-plugin") }
        maven { url = uri("https://maven.aliyun.com/repository/spring") }
        maven { url = uri("https://maven.aliyun.com/repository/spring-plugin") }
        mavenCentral()
    }

    publishing {
        repositories {
            maven {
                name = "localRepo"
                url = uri("file://$repoPath")
            }
        }
    }
}