svs-core/apps/svs-all-in-one/build.gradle.kts

group = "llh.svs"
version = rootProject.version

plugins {
    id("java")
    id("io.spring.dependency-management")
    id("org.springframework.boot")
    kotlin("jvm")
    kotlin("plugin.spring")
    kotlin("plugin.jpa")
}

dependencies {
    api(platform(project(":platform")))
    implementation(kotlin("reflect"))
    implementation(kotlin("stdlib-jdk8"))
    implementation("org.jetbrains.kotlinx:kotlinx-coroutines-core")
    implementation("org.jetbrains.kotlinx:kotlinx-coroutines-reactive")
    implementation("net.sourceforge.jexcelapi:jxl")
    implementation("commons-io:commons-io")
    implementation("org.apache.commons:commons-dbcp2")
    implementation("cc-lotus.gaf3:gaf-core-shared")
    implementation("cc-lotus.gaf3:gaf-core-services")
    implementation("cc-lotus.gaf3:gaf-core-gateway")
    implementation("com.alibaba:fastjson")
    implementation("io.jsonwebtoken:jjwt-api")
    implementation("io.jsonwebtoken:jjwt-impl")
    implementation("io.jsonwebtoken:jjwt-jackson")
    implementation("org.springframework.cloud:spring-cloud-starter-openfeign")
    implementation("org.springframework.boot:spring-boot-starter-data-jpa")
    implementation("org.springframework.boot:spring-boot-starter-data-redis")
    implementation("org.springframework.boot:spring-boot-starter-webflux")
    implementation("com.fasterxml.jackson.module:jackson-module-kotlin")
    implementation("org.springframework.boot:spring-boot-configuration-processor")
    implementation("org.springframework.cloud:spring-cloud-starter-gateway")
    implementation("org.springframework.cloud:spring-cloud-gateway-webflux")
    implementation("io.github.openfeign:feign-jackson:10.9")
    implementation("org.mongodb:bson")
    implementation("com.belerweb:pinyin4j:2.5.1")
    implementation(project(path = ":services:service-system", configuration = "lib"))
    implementation(project(path = ":services:service-task", configuration = "lib"))
    implementation(project(path = ":shared", configuration = "lib"))
    implementation("com.squareup.okhttp3:okhttp:4.10.0-RC1")
    implementation("com.github.oshi:oshi-core:6.1.4")
    runtimeOnly("mysql:mysql-connector-java")
    runtimeOnly(fileTree("$rootDir/libs") { include("*.jar") })
}


dependencyManagement {
    imports {
        mavenBom("org.springframework.cloud:spring-cloud-dependencies:${property("springCloudVersion")}")
    }
}

tasks.register<Sync>("script") {
    from("script")
    into("$buildDir/script")

    val disableAppVersion: String? by project
    if (disableAppVersion == "true") {
        expand("name" to project.name, "version" to version)
    } else {
        expand("name" to "${project.name}-$version", "version" to version)
    }
}

tasks.register<Copy>("dist") {
    dependsOn(tasks.named("bootJar"), tasks.named("script"))
    into("$rootDir/dist/${project.name}")
    from(tasks["bootJar"].outputs)
    from("$buildDir/script")
}